use AppleScript version "2.4" -- Yosemite (10.10) or later
use scripting additions

tell application "NeoFinder"
	set myList to selected items -- get a list of all selected items
end tell

if myList = missing value then -- that happens if nothing is selected in NeoFinder. But we need a selection!
	display dialog "Bitte selektieren Sie zuerst einige Dateien im NeoFinder!" buttons {"OK"} default button "OK" with icon caution
	return 0
end if

set numItems to count myList


-- tell the user what the script does and allow to cancel
set theResponse to display dialog "Dieses Scriptbenutzt den Dateinamen der " & numItems & " ausgewählten MOV-Dateien, konvertiert sie in ein Datum, und setzt dieses Datum als EXIF-Erstelldatum der Datei." & return & "Das erfordert Dateinamen im Format: '2001-05-15 12_24_00.mov' mit dem Datum und der Uhrzeit." buttons {"OK", "Abbrechen"} default button "Abbrechen" with icon caution
if button returned of theResponse = "Abbrechen" then
	return 0
end if


tell application "NeoFinder"
	set myList to selected items
	repeat with theItem in myList
		set myName to name of theItem
		if (myName ends with ".mov") and (length of (myName) > 21) then --  only .mov video files for this example
			set myDate to current date --  use that as a base date
			set year of myDate to (text 1 thru 4 of myName) as number
			set month of myDate to (text 6 thru 7 of myName) as number
			set day of myDate to (text 9 thru 10 of myName) as number
			set hours of myDate to (text 12 thru 13 of myName) as number
			set minutes of myDate to (text 15 thru 16 of myName) as number
			set seconds of myDate to (text 18 thru 19 of myName) as number
			set exif Capture Date of theItem to myDate --  write back the newly created date into the EXIF section of the movie file
		end if
	end repeat
end tell
